 طرز استفاده از Resource در VB: | |
آیا تا به حال برایتان پیش آمده است که عکس یا صدا یا فیلم و... را داشته باشید و بخواهید کاری کنید که این فایلها در خود برنامه تان ذخیره شود و در فایلهای جداگانه نباشد؟ در ویژوال بیسیک قسمتی وجود دارد که در آن می توانید فایلهایتان را دخیره کنید. این قسمت Resource نام دارد. حال کارمان را شروع می کنیم.
یک پروجکت ایجاد کنید، از منوی Add-ins گزینه Add-ins Manager را انتخاب کنید. گزینه VB 6 Resource Editor را پیدا کنید و در قسمت پایین گزینه Loaded/Unloaded (برای ایجاد برنامه به طور موقت) و گزینه Load on Startup (برای ایجاد برنامه برای همیشه) را انتخاب کرده و Ok را بزنید. حال گزینه Add New Resource File را از منوی Project انتخاب کنید. پنجره ای در مقابل شما ظاهر می شود که در آن باید فایلی با فرمت Res را در محلی ذخیره کنید.
در پنجره Project روی علامت + در گزینه Related Documents کلیک کنید و روی فایل Res دابل کلیک کنید. سپس پنجره Resource Editor باز می شود ، در قسمت بالا روی هر دکمه ای که کلیک کنید عملی انجام می شود، برای مثال روی آیکون Add icon کلیک کنید تا پنجره ای جلوی شما ظاهر شود ، شما از آنجا باید فایلهای ICO مورد نظر خود را انتخاب کنید. (شما می توانید از آیکونهایی که در مسیر C:\Program Files\Microsoft Visual Studio\ Common\ Graphics\Icons استفاده کنید)
معمولاً آیکونهای متنخب از 101 به بعد نامگذاری می شوند یعنی اگر شما دو آیکون انتخاب کرده باشید آنها 101 و 102 نام دارند. برای تغییر نام آنها روی آنها دابل کلیک کردن و نام مورد نظر را تایپ کنید. بر روی فرم یک دکمه بسازید و مشخصه Style آن را به Graphical تغییر دهید. حال روی آن دابل کلیک کنید و کدهای زیر را بنویسید:
Private Sub Command1_Click()
' Here is where we alternate the icons and the captions
If Command1.Caption = "Start" Then
Command1.Picture = LoadResPicture(101, vbResIcon)
Command1.Caption = "Stop"
Else
Command1.Picture = LoadResPicture(102, vbResIcon)
Command1.Caption = "Start"
End If
End Sub
Private Sub Form_Load()
' paste the icon on the face of the command button
' and set the caption. Look in the online help for
' additional information on the second parameter
Command1.Picture = LoadResPicture(102, vbResIcon)
Command1.Caption = "Start"
Show
End Sub
حال F5 را فشار دهید و روی دکمه کلیک کنید و ببینید چه اتفاقی می افتد. کد LoadResPicture یک عکس را نشان می دهد که درون پرانتز باید نام عکس در Resource Editor و بعد از آن نوعش را مشخص کنید. بقیه کدهای اجرا کننده فایلها عباتند از : LoadResData (فایلهای مختلف از جمله صوتی و تصویری) - LoadResPicture (برای فایلهای عکس و آیکون و...) - LoadResString (برای داده هایی که وارد کرده اید)
برای استفاده از قسمت سوم روی گزینه String Table در Resource Editor کلیک کنید ، سپس داده های مورد نظر را وارد کنید، برای مثال ۳ خانه از ۱۰۰۰۱ تا ۱۰۰۰۳ با نام English 101 و English 102 و English 103 ، ۳ خانه از ۲۰۰۰۱ تا ۲۰۰۰۳ با نام Arabic 101 و Arabic 102 و Arabic 103 و ۳ خانه از ۳۰۰۰۱ تا ۳۰۰۰۳ با نام Spanish 101 و Spanish 102 و Spanish 103 ايجاد کنيد.
حال در فرم 5 دکمه و 3 برچسب ایجاد کنید و کدهای زیر را وارد کنید:
Option Explicit
' In the RES file, place the cursor on the ID number
' (it will not highlight) and type over it. I
' separated them by increments of 10,000 because
' these are languages. My preference.
'
' These variables should probably be Public in a BAS
' module prefixed with "g_" for easy identification.
' Curently I have these identified as module level
' variables. Prefixed with "m_"
'
Private m_lngIndex As Long
Private m_bEnglish As Boolean
Private m_bArabic As Boolean
Private m_bSpanish As Boolean
Private Sub cmdChoice_Click(Index As Integer)
' Select the language flags
Select Case Index
Case 0: ' English
m_bEnglish = True
m_bArabic = False
m_bSpanish = False
m_lngIndex = 0 ' If English, we add nothing
Case 1: ' Arabic
m_bEnglish = False
m_bArabic = True
m_bSpanish = False
m_lngIndex = 10000 ' Increment by 10000
Case 2: ' Spanish
m_bEnglish = False
m_bArabic = False
m_bSpanish = True
m_lngIndex = 20000 ' Increment by 20000
End Select
End Sub
Private Sub cmdDisplay_Click()
' display the language of choice
lblChoice(0) = LoadResString(10001 + m_lngIndex)
lblChoice(1) = LoadResString(10002 + m_lngIndex)
lblChoice(2) = LoadResString(10003 + m_lngIndex)
End Sub
Private Sub cmdExit_Click()
Unload Me
End Sub
Private Sub Form_Load()
Dim i As Integer
For i = 0 To 2
lblChoice(i) = "" ' clear the labels
Next
cmdChoice_Click 0 ' default to English
Show ' show the form
End Sub
Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
Unload Me ' deactivate form
Set Form1 = Nothing ' free object from memory
End Sub
چنانچه دکمه F5 را بزنید و با برنامه کار کنید می بینید که برای نمایش داده ها بر روی برچسبها از داده های درون Resource Editor استفاده شده است.
امیدوارم که از این قسمت بهره لازم را برده باشید. | 
